      SUBROUTINE FOINI (OPCODE, BUFFER, DISK, CNO, VER, CATBLK, LUN,
     *   IFORNO, FOKOLS, FONUMV, NUMANT, NUMIF, IERR)
C-----------------------------------------------------------------------
C! Creates/opens/initializes frequency offset (FO) table
C# EXT-appl Calibration
C-----------------------------------------------------------------------
C;  Copyright (C) 2009, 2021
C;  Associated Universities, Inc. Washington DC, USA.
C;
C;  This program is free software; you can redistribute it and/or
C;  modify it under the terms of the GNU General Public License as
C;  published by the Free Software Foundation; either version 2 of
C;  the License, or (at your option) any later version.
C;
C;  This program is distributed in the hope that it will be useful,
C;  but WITHOUT ANY WARRANTY; without even the implied warranty of
C;  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
C;  GNU General Public License for more details.
C;
C;  You should have received a copy of the GNU General Public
C;  License along with this program; if not, write to the Free
C;  Software Foundation, Inc., 675 Massachusetts Ave, Cambridge,
C;  MA 02139, USA.
C;
C;  Correspondence concerning AIPS should be addressed as follows:
C;         Internet email: aipsmail@nrao.edu.
C;         Postal address: AIPS Project Office
C;                         National Radio Astronomy Observatory
C;                         520 Edgemont Road
C;                         Charlottesville, VA 22903-2475 USA
C-----------------------------------------------------------------------
C   Creates and initializes frequency offset extension tables.
C   Inputs:
C      OPCODE   C*4      Operation code:
C                           'WRIT' = create/init for write or read
C                           'READ' = open for read only
C      BUFFER   I(512)   I/O buffer and related storage, also defines
C                           file if open.
C      DISK     I        Disk to use.
C      CNO      I        Catalog slot number
C      VER      I        FO file version
C      CATBLK   I(256)   Catalog header block.
C      LUN      I        Logical unit number to use
C   Input/output
C      NUMANT   I        Number of antennas
C      NUMIF    I        Number of IF pairs
C   Output:
C      ICLRNO   I        Next scan number, start of the file if 'READ',
C                           the last+1 if WRITE
C      CLKOLS   I(6)     The column pointer array in order
C      CLNUMV   I(6)     Element count in each column.
C      IERR     I        Return error code, 0=>OK, else TABINI or TABIO
C                           error.
C-----------------------------------------------------------------------
      INTEGER   MAXFOC
      PARAMETER (MAXFOC = 7)
C
      CHARACTER OPCODE*4
      INTEGER   BUFFER(512), DISK, CNO, VER, CATBLK(256), LUN, IFORNO,
     *   FOKOLS(MAXFOC), FONUMV(MAXFOC), NUMANT, NUMIF, IERR
C
      HOLLERITH HOLTMP(6)
      CHARACTER TTITLE*56, TITLE(MAXFOC)*24, UNITS(MAXFOC)*8, KEYW(3)*8
      INTEGER   NKEY, NREC, DATP(128,2), NCOL, NTT, DTYP(MAXFOC), NDATA,
     *   KLOCS(3), KEYVAL(3), IPOINT, JERR, J, KEYTYP(3), I, REVNO,
     *   MSGSAV, NC, JTRIM, FOREVN, ITEMP(6)
      LOGICAL   T, DOREAD, NEWFIL
      INCLUDE 'INCS:DMSG.INC'
      INCLUDE 'INCS:DDCH.INC'
      EQUIVALENCE (HOLTMP, ITEMP)
      DATA T /.TRUE./
      DATA TTITLE /'AIPS UV DATA FILE FREQUENCY OFFSET TABLE'/
C                                       Values >10 are scalar
      DATA DTYP /11,12,4*14,2/
C                                       NOTE: Change PCLTAB.INC when
C                                       changing the table columns.
      DATA TITLE /'TIME', 'TIME INTERVAL', 'SOURCE ID', 'ANTENNA NO.',
     *   'SUBARRAY', 'FREQ ID', 'DOPPOFF'/
      DATA KEYW /'NO_ANT', 'NO_IF', 'REVISION'/
      DATA UNITS /'DAYS','DAYS', 4*' ', 'HZ'/
      DATA FOREVN /1/
C-----------------------------------------------------------------------
C                                       Check OPCODE
      DOREAD = OPCODE.EQ.'READ'
C                                       Open file
      NREC = 1000
      NCOL = MAXFOC
      IF (DOREAD) NCOL = 0
      NKEY = 3
      NDATA = MAXFOC
      CALL FILL (NDATA, 0, FOKOLS)
      CALL FILL (NDATA, 0, FONUMV)
C                                       Fill in types
      IF (.NOT.DOREAD) THEN
         CALL COPY (NDATA, DTYP, DATP(1,2))
         DO 10 J = 1,NDATA
            IF (DTYP(J).LT.10) DATP(J,2) = DTYP(J) + 10 * NUMIF
 10         CONTINUE
         END IF
C                                       Create/open file
      CALL TABINI (OPCODE, 'FO', DISK, CNO, VER, CATBLK, LUN, NKEY,
     *   NREC, NCOL, DATP, BUFFER, IERR)
      IF (IERR.GT.0) THEN
         CALL TABERR (OPCODE, 'TABINI', 'CALINI', IERR)
         GO TO 990
         END IF
      NEWFIL = IERR.LT.0
C                                       Get number of records
      IFORNO = BUFFER(5) + 1
      IF (DOREAD) IFORNO = 1
      NKEY = 3
      MSGSAV = MSGSUP
C                                       File created, initialize
      IF (NEWFIL) THEN
C                                       Col. labels.
         DO 40 I = 1,NCOL
            CALL CHR2H (24, TITLE(I), 1, ITEMP)
            CALL TABIO ('WRIT', 3, I, ITEMP, BUFFER, IERR)
            IF (IERR.GT.0) THEN
               CALL TABERR ('WRIT', 'TABIO', 'CALINI', IERR)
               GO TO 990
               END IF
C                                       Units
            CALL CHR2H (8, UNITS(I), 1, ITEMP)
            CALL TABIO ('WRIT', 4, I, ITEMP, BUFFER, IERR)
            IF (IERR.GT.0) THEN
               CALL TABERR ('WRIT', 'TABIO', 'CALINI', IERR)
               GO TO 990
               END IF
 40         CONTINUE
C                                       Fill in Table title
         NTT = JTRIM (TTITLE)
         CALL CHR2H (NTT, TTITLE, 1, BUFFER(101))
C                                       Set keyword values
C                                       No. antennas.
         KLOCS(1) = 1
         KEYTYP(1) = 4
         KEYVAL(1) = NUMANT
C                                       No. IFs
         KLOCS(2) = 2
         KEYTYP(2) = 4
         KEYVAL(2) = NUMIF
C                                       Revision number from PCLTAB.INC
         REVNO = FOREVN
         KLOCS(3) = IPOINT
         KEYTYP(3) = 4
         KEYVAL(3) = REVNO
C                                       Only write if just created.
         CALL TABKEY (OPCODE, KEYW, NKEY, BUFFER, KLOCS, KEYVAL, KEYTYP,
     *      IERR)
         IF ((IERR.GE.1) .AND. (IERR.LE.20)) THEN
            CALL TABERR ('WRIT', 'TABKEY', 'CALINI', IERR)
            GO TO 990
            END IF
C                                       Read keywords
      ELSE
         MSGSUP = 32000
         CALL TABKEY ('READ', KEYW, NKEY, BUFFER, KLOCS, KEYVAL, KEYTYP,
     *      IERR)
         MSGSUP = MSGSAV
         IF ((IERR.GE.1) .AND. (IERR.LE.20)) THEN
            CALL TABERR ('READ', 'TABKEY', 'CALINI', IERR)
            GO TO 990
            END IF
C                                       Retrieve keyword values
C                                       No. antennas.
         IPOINT = KLOCS(1)
         IF (IPOINT.GT.0) NUMANT = KEYVAL(IPOINT)
C                                       No. IF pairs
         IPOINT = KLOCS(2)
         IF (IPOINT.GT.0) NUMIF = KEYVAL(IPOINT)
C                                       Revision level
         IPOINT = KLOCS(3)
         REVNO = -1
         IF (IPOINT.GT.0) REVNO = KEYVAL(IPOINT)
         END IF
C                                       Get array indices
C                                       Cover your ass from FNDCOL -
C                                       close to flush the buffers and
C                                       then reopen.
      CALL TABIO ('CLOS', 0, IPOINT, KEYVAL, BUFFER, IERR)
      IF (IERR.GT.0) THEN
         CALL TABERR ('CLOS', 'TABIO', 'CALINI', IERR)
         GO TO 990
         END IF
      NKEY = 0
      CALL TABINI (OPCODE, 'FO', DISK, CNO, VER, CATBLK, LUN, NKEY,
     *   NREC, NCOL, DATP, BUFFER, IERR)
      IF (IERR.GT.0) THEN
         CALL TABERR (OPCODE, 'TABINI', 'CALINI', IERR)
         GO TO 990
         END IF
      CALL FNDCOL (MAXFOC, TITLE, 24, T, BUFFER, FOKOLS, JERR)
C                                      Get array indices and no. values
      NCOL = MAXFOC
      DO 150 I = 1,NCOL
         IPOINT = FOKOLS(I)
         IF (IPOINT.GT.0) THEN
            FOKOLS(I) = DATP(IPOINT,1)
            FONUMV(I) = DATP(IPOINT,2) / 10
            IF (FONUMV(I).LE.0) THEN
               NC = JTRIM (TITLE(I))
               WRITE (MSGTXT,1100) TITLE(I)(:NC)
               CALL MSGWRT (6)
               END IF
         ELSE
            FOKOLS(I) = -1
            FONUMV(I) = 0
            NC = JTRIM (TITLE(I))
            WRITE (MSGTXT,1101) TITLE(I)(:NC)
            CALL MSGWRT (6)
            END IF
 150     CONTINUE
      GO TO 999
C                                       Error
 990  WRITE (MSGTXT,1990) OPCODE
      CALL MSGWRT (7)
C
 999  RETURN
C-----------------------------------------------------------------------
 1100 FORMAT ('FOINI: ''',A,''' COLUMN HAS NO VALUES')
 1101 FORMAT ('FOINI: ''',A,''' COLUMN NOT FOUND')
 1990 FORMAT ('FOINI: ERROR INITIALIZING CALIBRATION TABLE FOR ',A4)
      END
